Getting rid of all the "sharing" stuff

SeaDrive
1

Hey, I use Seafile alone, there’s only 1 used and that’s me and that’s not going to change anytime soon.

I’ve installed Seadrive client for windows - all working good so far, but what annoys me is that when i click SeaDrive in the left taskbar in Explorer, it shows me 4 folders:

  • My Library
  • Shared with all
  • Shared with groups
  • Shared with me

While My library makes some sense to me, the other 3 don’t since nothing will be shared with anyone since i am the only user. Is there some option somewhere that can disable these folders? i’ve tried reading the manual, and all i come up with is CLOUD_MODE but that only hides 1 out of 3 folders, and only in web client, not in SeaDrive.

Thanks!

2

Welcome to the Seafile Community Forum.

Unfortunately, there is no such option.

3

Creating a link in the ‘Quick access’ folder could be an alternative solution to save you some clicks.

1 Like
4

image
image358×779 13 KB

This is a workaround, but it works well enough for me. Put this into a “.bat” file and change sf_user to the name of the directory in seadrive_root

:: Randomly generated GUID
set guid=D032E38D-B063-4DA2-8E2D-CF678021B38E
set sf_user=Facundo
set name=SeaDrive (%sf_user%/My Libraries)
set folder=%%userprofile%%\seadrive_root\%sf_user%\My Libraries
set icon=%%programfiles%%\SeaDrive\bin\seadrive.exe,0

reg add HKCU\Software\Classes\CLSID\{%guid%} /ve /t REG_SZ /d "%name%" /f
reg add HKCU\Software\Classes\CLSID\{%guid%}\DefaultIcon /ve /t REG_EXPAND_SZ /d "%icon%" /f
reg add HKCU\Software\Classes\CLSID\{%guid%} /v System.IsPinnedToNameSpaceTree /t REG_DWORD /d 0x1 /f 
reg add HKCU\Software\Classes\CLSID\{%guid%} /v SortOrderIndex /t REG_DWORD /d 0x42 /f
reg add HKCU\Software\Classes\CLSID\{%guid%}\InProcServer32 /ve /t REG_EXPAND_SZ /d %%systemroot%%\system32\shell32.dll /f
reg add HKCU\Software\Classes\CLSID\{%guid%}\Instance /v CLSID /t REG_SZ /d {0E5AAE11-A475-4c5b-AB00-C66DE400274E} /f
reg add HKCU\Software\Classes\CLSID\{%guid%}\Instance\InitPropertyBag /v Attributes /t REG_DWORD /d 0x11 /f
reg add HKCU\Software\Classes\CLSID\{%guid%}\Instance\InitPropertyBag /v TargetFolderPath /t REG_EXPAND_SZ /d "%folder%" /f
reg add HKCU\Software\Classes\CLSID\{%guid%}\ShellFolder /v FolderValueFlags /t REG_DWORD /d 0x28 /f
reg add HKCU\Software\Classes\CLSID\{%guid%}\ShellFolder /v Attributes /t REG_DWORD /d 0xF080004D /f
reg add HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\Desktop\NameSpace\{%guid%} /ve /t REG_SZ /d "%name%" /f
reg add HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer\HideDesktopIcons\NewStartPanel /v {%guid%} /t REG_DWORD /d 0x1 /f

pause
5 Likes
5

thanks for this! this is probably as close as it can be!

6

Thanks for the script. I had used something similar with the Winaero tool where you can add your own “shortcuts” to the navigation pane, but I prefer yours. I really do wish that they would make more options in regards to this structure. Atleast cook the 3 “Shared with” folders down to one, optionally if nothing else.

I made a combined powershell script that adds a seperate entry for “My Libraries” and “Shared files” (which is linking to ‘Shared with me’, the only folder of the “shared with” ones that are relevant for me). The Powershell script then searches the CLSID key in the registry for the default SeaDrive entry, and hides it. The reason being that I’ve experienced the UUID SeaDrive itself uses can also change between versions.

image